OPGELOST- Formule om uren te berekenen vervolg

Bespreek het rekenblad
Leen
Berichten: 17
Lid geworden op: di aug 25, 2009 10:07 am

OPGELOST- Formule om uren te berekenen vervolg

Bericht door Leen »

goeie morgen iedereen,

ge gelooft het of niet, maar er moet nog een vervolg komen op mijn vorige vraag :) (vraag van 25-12-2009)

de formule die Johan me heeft gegeven klopt als een bus, maar er moet nog een voorwaarde bijkomen. Volgende formule wordt momenteel gebruikt:
=ALS(H4<>"";ALS(I4<>"";ALS(I4>H4;(I4-H4)*2;(I4+1-H4)*2);"");"")

volgende voorwaarde zou er nog moeten bijkomen: de actieve nachturen moeten nog begrensd worden tot maximum 5 uur. Dus als ik 2.5 uur effectief werk, krijg ik maximum 5 uur actieve nacht (kolom L) als premie, aangevuld met 3 uur slapende nacht (kolom M).
Hoe zat het nu weer precies?
voor uren gepresteerd vanaf 23 uur en dat ik actief aan het werk ben, krijg ik een extra premie. Stel dat ik zou werken van 23 tot 1 uur, is in totaal 2 uur gepresteerd, zou me als premie 4 uur actieve nacht geven, aangevuld met 3 uur slapende nacht. Op de formule die nu wordt gebruikt staat geen maximum op, en die grens zou er dus nog moeten bijkomen.

wie kan me helpen om deze grens ook nog in die formule verwerkt te krijgen?
in bijlage het rekenblad waar de gebruikte formules in staan.
bij voorbaat al van harte bedankt.

grtz

Leen
Bijlagen
test.ods
(31.96 KiB) 373 keer gedownload
Laatst gewijzigd door Leen op ma jan 18, 2010 11:35 am, 1 keer totaal gewijzigd.
Windows Vista Home
Open Office Org 3.0.0
eremmel
Berichten: 670
Lid geworden op: di sep 01, 2009 10:11 am
Locatie: Barneveld, Nederland

Re: Formule om uren te berekenen vervolg

Bericht door eremmel »

Leen,

Ik hoop dat je deze reactie niet vervelend vindt, maar nu je een aantal keren bent geholpen en natuurlijk e.e.a. hebt proberen te begrijpen is het misschien een idee om te proberen zelf die wijziging te maken en je resultaat te delen met het forum en zo samen naar een oplossing toe te werken. Op deze manier neemt je ervaring en zelfstandigheid toe.
Nu wil ik je de volgende hint geven, als je die nu probeert te verwerken in de formule die je liet zien ...
Wiskundig gezien kun je het maximaliseren van een berekening vergelijken met het nemen van de minimale waarde van de berekening én de grens van 5 uur.
Probeer:
- via de help de functie te vinden voor de minimale waarde
- deze op de juiste plaats in de formule te zetten.
en laat weten hoe ver je komt.

Erik
W11 21H2 (build 22000), LO 7.4.1.2(x64)
Het is Microsoft marketing die laat geloven dat computers geschikt zijn voor niet technici
Leen
Berichten: 17
Lid geworden op: di aug 25, 2009 10:07 am

Re: Formule om uren te berekenen vervolg

Bericht door Leen »

Hallo Erik,

natuurlijk vind ik je reactie niet vervelend ! Meer nog, eigenlijk vind ik zelf ook wel dat je gelijk hebt hoor !
Het enige probleem is dat ik eigenlijk maar heel weinig ken van Calculator en het bij momenten voor mij niet zo simpel is om tot een oplossing te komen.

Maar ik ga dus zeker een poging wagen ! Ik heb trouwens die functie assistent ondertussen gevonden :D
En nu maar hopen dat die mij al een eind op weg kan helpen.

Ik houd je zeker op de hoogte van het resultaat.

grtz

Leen
Windows Vista Home
Open Office Org 3.0.0
Johan
Berichten: 496
Lid geworden op: di jun 02, 2009 11:53 pm

Re: Formule om uren te berekenen vervolg

Bericht door Johan »

Van de formule

Code: Selecteer alles

=ALS(H4<>"";ALS(I4<>"";ALS(I4>H4;(I4-H4)*2;(I4+1-H4)*2);"");"")
Is onderstaande

Code: Selecteer alles

=ALS(I4>H4;(I4-H4)*2;(I4+1-H4)*2)
het belangrijkste stukje.

Code: Selecteer alles

=ALS(H4<>"";ALS(I4<>"";...;"");"")
Het net bovenstaande heeft enkel iets te zien met de opmaak. Succes!! ;)
Leen
Berichten: 17
Lid geworden op: di aug 25, 2009 10:07 am

Re: Formule om uren te berekenen vervolg

Bericht door Leen »

goeie morgen,

ik denk dat ik het gevonden heb :D

ik heb wel een extra kolom moeten toevoegen, maar zo werkt het ook volgens mij (kijk maar eens naar de bijlage).

als ik het op de manier zou moeten doen zoals Erik voorstelde, was het me te ingewikkeld, dus doe ik het op de volgende manier:
ik heb dus een kolom toegevoegd en daar de volgende formule ingeplakt
=ALS(H4<>"";ALS(I4<>"";ALS(I4>H4;(I4-H4)*2;(I4+1-H4)*2);""))
deze stond eerst in mijn kolom totaal
dan heb ik in mijn kolom actieve nacht volgende formule ingeplakt
=ALS(U4<>"";ALS(U4>$M$1;$M$1;U4))
en in cel M1 gewoon 5:00 in gezet.

Moest het toch nog anders kunnen, zonder die extra kolom te moeten toevoegen, zou natuurlijk geweldig zijn, maar daar geraak ik maar niet wijs uit :oops:

Ik heb nog een groter probleem ontdekt ondertussen :( thuis werk ik onder windows, maar op mijn werk werken we onder linux, met als gevolg dat ik dus steeds een foutmelding krijg in de kolom totaal zolang de kolommen h en i niet zijn ingevuld.

weet iemand hoe ik dit kan oplossen?

grtz

Leen
Bijlagen
test.ods
(32.91 KiB) 349 keer gedownload
Windows Vista Home
Open Office Org 3.0.0
eremmel
Berichten: 670
Lid geworden op: di sep 01, 2009 10:11 am
Locatie: Barneveld, Nederland

Re: Formule om uren te berekenen vervolg

Bericht door eremmel »

De fout in de totaal kolom komt waarschijnlijk van de berekening op de kolommen H, I omdat er een ALS(..) in zit die rekent met lege velden.

De lastige dag overgang voor de nacht uren kunnen we makkelijker maken met een wiskundig truukje. Als je het verschil uit rekent tussen 23:00 en 1:00 dan moet je één dag lenen (Eén dag is in calc het getal 1 = 24:00). Dus 24:00 + 1:00 - 23:00 = 2:00. We weten dat het antwoord altijd kleiner is dan één dag. Dus als we van 23:00 tot 23:59 moeten rekenen, dan kunnen we nog steeds één dag lenen:
24:00 + 23:30 -23:00 = 24:30 = 1 plus een beetje. Er is een REST functie die we mooi kunnen gebruiken. De formule wordt dan:
REST(1+I4-H4;1).
Dus de ALS(..) berekening uit kolom J zou u kunnen vervangen door ALS(H4=I4;0;REST(1+I4-H4;1)). Ik denk dat dit dan geen error meer geeft op linux (zou trouwens niet moeten).

De door u gemaakte =ALS(...) (kolom L) functie is prima en e.e.a. wordt wel erg ingewikkeld als u dat nog weer eens zou combineren met de functie uit kolom U. Ik probeerde u te sturen om een andere functie te gebruiken. U kunt namelijk kolom L vervangen door: =MIN($M$1;U4)
Ik denk dat u ook kolom L en kolom U kunt combineren tot kolom L:
=ALS(H4=I4;""; MIN(2*REST(1+I4-H4;1);$M$1)
uitleg:
=ALS(H4=I4;""; -------------- Toon geen waarde als H4 en I4 gelijk zijn, dit is inclusief niet ingevuld.
MIN( --------------------------Topde dubbel gerekende uren af op $M$1
2*REST(1+I4-H4;1)-----------Verdubbel de nacht uren.
;$M$1)


De formule voor Sl.Waak (kolom M) kan nu ook veel eenvoudiger worden omdat de waarde uit kolom L nooit meer dan 5 uur kan zijn, dus de controle op meer dan 8 uur is niet nodig. Het enige waar ik nog mee zit is dat u eerder sprak over dat de sl.waak uren afgetopt moeten worden op 3 en dat het aantal bepaald wordt door 7 - Act. Nacht (kolom L), maar dat er in de laatste werkblad 8 - Act. Nacht (kolom L) staat. U kunt echter nu kolom M vervangen door:
=ALS(L4="";"";MIN(8/24-L4;3/24))
Maar als Kolom L altijd afgetopt wordt op 5 is het aantal sl.waak uren altijd 3!!!
Misschien moet voor het berekenen van de sl.waak uren de dubbele uren genomen worden, maar dan niet afgetopt? Dan kunnen we voor kolom M schrijven (we toppen dan af op 8 ipv 5 vanwege de aftreksom 8 - uren):
=ALS(L4="";"";MIN(8/24 - MIN(8/24; 2*REST(1+I4-H4;1)) ;3/24))

Ik zou u nog een tip willen geven mbt veilige invoer van gegevens. U werkt met uren, maar als u per ongeluk meer dan 1 dag invult dan ziet u dat niet, maar wordt er wel mee gerekend. Probeer maar eens in kolom D in te vullen =13/24 en =1+13/24 (Vul bij kolom E dan 14:00 in) het zelfde wordt getoond maar er staat niet het zelfde. U kunt met 'voorwaarderlijke opmaak' eventueel die cellen markeren die mogelijk een foute invoer bevatten. Te denken valt aan (als voorbeeld voor de middag):
Van > Tot: bv 16:00 , 13:00
Van < 12:00
Tot > 18:00
en eventueel Van = Tot moet worden leeg gelaten...
Geef maar aan of dat een optie voor u is...

Al met al een heel verhaal, maar dit gaat u een cursus schelen ;)
W11 21H2 (build 22000), LO 7.4.1.2(x64)
Het is Microsoft marketing die laat geloven dat computers geschikt zijn voor niet technici
Leen
Berichten: 17
Lid geworden op: di aug 25, 2009 10:07 am

OPGELOST - Re: Formule om uren te berekenen vervolg

Bericht door Leen »

hallo Erik,

bedankt voor je hulp bij het oplossen van mijn probleem van actieve en slapende nacht. Ik had me steeds vergist, de grens van de actieve nacht is steeds max. 5 geweest, zodat de slapende automatisch werd begrensd op 3 uur.

De tip rond veilige invoer van gegevens is me nog niet helemaal duidelijk hoe het daar nu precies mee zit, maar daar ga ik me nu niet in verdiepen. Ik ben héééééééééééél tevreden met de formules die je me nu hebt bezorgd en ik geloof wel dat ik nogal goed ben in het registreren van mijn gewerkte uren :D

Ik wil je in ieder geval nog is van harte bedanken voor alle hulp.

Leen
PS En inderdaad dit scheelde me een cursus, maar toch denk ik dat ik me is ergens ga inschrijven, om een beetje meer mee te kunnen in de wondere wereld van calculator. ;)

En nu zo ik het nog moeten klaar spelen om opgelost voor mijn vraag te krijgen en dat groene vinkje, maar dat wil me echt niet lukken, en ik weet dus niet wat ik fout doe ! Ik weet dat ik dit voor mijn beginvraag moet zetten, maar ik geraak daar maar niet aan, om OPGELOST voor te krijgen. Als iemand me dat nog is wil duidelijk maken :oops:
Windows Vista Home
Open Office Org 3.0.0
Johan
Berichten: 496
Lid geworden op: di jun 02, 2009 11:53 pm

Re: Formule om uren te berekenen vervolg

Bericht door Johan »

Als u zich inlogt, ziet u rechts bovenaan uw eerste post, links van uw naam Leen Afbeelding staan? :D U klikt daarop en u krijgt een nieuw scherm? Nu kan u uw beginpost gaan wijzigen. Iets in de zin van:
Afbeelding
Heeft u iets aan deze uitleg? 8-)
Leen
Berichten: 17
Lid geworden op: di aug 25, 2009 10:07 am

Re: OPGELOST- Formule om uren te berekenen vervolg

Bericht door Leen »

Bedankt Johan,

ik heb dit in 1 keer gedaan, dankzij jou uitleg. Soms voel ik me echt een super uilskuiken :D

grtz

Leen
Windows Vista Home
Open Office Org 3.0.0
Johan
Berichten: 496
Lid geworden op: di jun 02, 2009 11:53 pm

Re: OPGELOST- Formule om uren te berekenen vervolg

Bericht door Johan »

Leen schreef: Soms voel ik me echt een super uilskuiken :D
Zolang u beseft dat u daarin niet altijd de enige bent ... ;) :roll: :shock:
Plaats reactie