[Résolu] [Calc] Info sur une feuille scindée : fenêtre figée

[xank]

Bonjour,

Je sais comment figer une fenêtre à l'aide de l'enregistreur de macro mais à l'inverse je ne trouve pas comment récupérer l'adresse de cellule à partir de laquelle a lieu l'opération de scinder la fenêtre ?

J'espère avoir été clair ?

[xank]

Voici donc donc les versions

Versions :
OS : Win XP SP2
OOO : 2.0.2

Merci de m'avoir répondu.

[xank]

Voici une solution (qui peut être améliorée) :

Code : Tout sélectionner

REM  *****  BASIC  *****

Sub Figer

' Au départ, seule la feuille 1 est figée
' Cette procédure permet de figer la feuille 2
' selon les mêmes caractéristiques de la feuille 1
' Si la fenêtre est seulement scindée, il n'y a
' aucun effet.

Dim DocControl As Object
DocControl = ThisComponent.CurrentController

' Active la première feuille
DocControl.ActiveSheet = ThisComponent.Sheets(0)

' Récupère la colonne (figée ou scindée)
Col = DocControl.getSplitColumn

' Récupère la ligne (figée ou scindée)
Lig = DocControl.getSplitRow

If (Col > 0 Or Lig > 0) And Not(DocControl.getIsWindowSplit()) Then

	' Condition importante : en effet si la feuille 1
	' n'est pas figée, la feuille 2 sera figée à
	' l'endroit où se trouve la sélection (cellule)
	' 
	' Le getIsWindowsSplit est égal à :
	' - True si Fenêtre scindée
	' - False si Fenêtre n'est pas scindée 
	'   mais elle peut être figée  (c'est ce que je veux)
	' Active la deuxième feuille	
	DocControl.ActiveSheet = ThisComponent.Sheets(1)

	' Fige
	DocControl.FreezeAtPosition(Col,Lig)

End If

End Sub

Merci d'avoir prêter attention à mon problème.

[c-stefan]

Bonsoir,

si votre problème est résolu merci de mettre la balise dans le titre de votre 1er poste.

une aide pour savoir comment faire.
http://www.forum-openoffice.org/fichier ... resolu.swf

[xank]

Bonjour,

Le code peut se réduire à

Code : Tout sélectionner

Sub Figer

' Au départ, seule la feuille 1 est figée
' Cette procédure permet de figer la feuille 2
' selon les mêmes caractéristiques de la feuille 1
' Si la fenêtre est seulement scindée, il n'y a
' aucun effet.

Dim DocControl As Object
DocControl = ThisComponent.CurrentController

' Active la première feuille
DocControl.ActiveSheet = ThisComponent.Sheets(0)

' Teste si la feuille est figée
If DocControl.hasFrozenPanes Then

	' Récupère la colonne
	Col = DocControl.getSplitColumn

	' Récupère la ligne
	Lig = DocControl.getSplitRow

	' Active la deuxième feuille   
	DocControl.ActiveSheet = ThisComponent.Sheets(1)

	' Fige
	DocControl.FreezeAtPosition(Col,Lig)

End If

End Sub

La méthode hasFrozenPanes détecte si la feuille est figée.
C'est plus simple !