[Résolu][Calc] Copie d'une feuille dans un nouveau classeur

[Mobydick_62]

Bonjour à tous.
Malgré une longue recherche je n'ai malheureusement pas trouvé réponse à mon problème.
Mon problème est le suivant:
Depuis un fichier Calc (source), je crée un nouveau fichier Calc en y insérant l'une des feuilles de mon fichier source.
Jusqu'ici pas de problème. Par contre je veux donner un nom à mon nouveau fichier Calc et là, c'est le document source qui est renommé. De toute évidence si mon nouveau fichier est bien le premier visible à l'écran, il n'est pas activé. Malgré mes recherche je n'arrive pas à solutionner mon problème.
Je joins un fichier exemple avec ma macro.
Merci d'avance

[Churay]

Bonjour,

Par contre je veux donner un nom à mon nouveau fichier Calc et là, c'est le document source qui est renommé. De toute évidence si mon nouveau fichier est bien le premier visible à l'écran, il n'est pas activé.

Ton soucis vient effectivement de l'activation des fichiers. Via l'API, le code a de grandes chances d'être plus compact qu'avec le dispatcher utilisé par l'enregistreur.

Procédure :
- ouvrir le fichier source et lancer la macro qui
- sélectionne la zone à copier (la totalité de la feuille est efficace, certes... mais radicale )
- créer un fichier vide (il est actif)
- sélectionne la feuille de réception dans le nouveau fichier
- y copie la sélection précédente
- donne un nom et sauvegarde via .storeAsURL.

A ce stade c'est le fichier cible qui est activf, pour revenir sur la source, il suffit de sélectionner avec thisComponent.select(oObjet : oObjet étant une feuille, une cellule ou une plage de cellules de la source, pour que cette sélection soit active et donc le document source.

Plusieurs exemples sur le forum sont disponibles pour ce faire.

[luky-luke]

Bonjour,

Vite fait, en sortant d'une sieste estivale, et entièrement dans la langue de Shakespear (sauf les commentaires) pour ne choquer personne

Code : Tout sélectionner

Option Explicit
Sub Main
Dim MySheet As Object, NewSheet As Object
Dim SourceArea As Object, TargetArea As Object
Dim NewDoc As String, DisplaySource As Object
Dim MyFileName As String, addressDoc As String 

Mysheet = ThisComponent.Sheets(2) 'Le document Actif feuille 3
ThisComponent.CurrentController.ActiveSheet = MySheet
SourceArea = Mysheet.GetCellRangeByName("A1:F14") 'La zone à copier

NewDoc = "private:factory/scalc" 'Création d'un nouveau document
DisplaySource = StarDesktop.LoadComponentFromURL(NewDoc,"_blank",0,array())

MyFileName = "NewDoc.ods" 'Le Nom du nouveau document
'addressDoc = convertToURL("C:\NouveauDoc.ods" + MyFileName) ' et son adresse 
addressDoc = convertToUrl ("/home/luky-luke/Bureau/" + MyFileName) ' et son adresse 

NewSheet = DisplaySource.Sheets(2) ' Choix de la nouvelle feuille
DisplaySource.CurrentController.ActiveSheet = NewSheet 
TargetArea = NewSheet.GetCellRangeByName("A1:F14") 'La zone ou l'on copie
TargetArea.DataArray = SourceArea.DataArray 'La copie

DisplaySource.storeAsUrl(addressDoc,array()) 'l'enregistrement avec le nom

End Sub

Cordialement
Luke

[Mobydick_62]

Bonjour et merci à vous de m''avoir répondu rapidement.
Comme dit Churay : "copier la totalité de la feuille est efficace, certes... mais radicale". Mais l'avantage est que ma feuille cible est complètement identique à ma feuille source. Elle garde toutes les mises en formes (largeur colonnes, hauteur lignes, police de caractères.....ect...).

J'ai repris le code de luky-luke qui fonctionne très bien puisque j'arrive à nommer mon nouveau fichier calc là où je veux. Par contre le code repose sur la copie d'une zone de cellule. Dans le principe c'est parfait mais le problème est que dans mon nouveau classeur je perd toutes les mises en formes de ma feuille source.(largeur colonnes, hauteur lignes, police de caractères.....ect...).

En lisant le livre : Programmation OpenOffice.org 3 l'auteur dit, je cite "Si votre classeur comporte une feuille parfaitement formatée et remplie, il est avantageux de créer une feuille en faisant une copie de la première." Mais son exemple repose sur la copie d'une feuille et le collage dans un même classeur. C'est ce que je voudrais faire mais dans un nouveau classeur.

En reprenant le code de luki-luke, peut être est t'il possible de copier/collier une plage de cellule en gardant leurs mise en forme ?????? Je vais chercher.

[alhazred]

Bonjour à tous,

Utilisation exceptionnelle du dispatcher... pour copier la totalité de la feuille avec un code sans complications inutiles, pour conserver tous les formatages, ainsi que les dimensions de cellules.

Code : Tout sélectionner

REM  *****  BASIC  *****

Option Explicit

Sub Main
	Dim sourceDoc As Object, sourceSheet As Object
	Dim destDoc As Object, destSheet As Object, destURL As String
	      
	sourceDoc = thisComponent
	sourceSheet = sourceDoc.sheets.GetByName("Feuille2")
	
	destDoc = StarDesktop.LoadComponentFromURL("private:factory/scalc","_blank",0,array())
	destSheet = destDoc.sheets.GetByName("Feuille3")
	
	CopySheet sourceDoc,sourceSheet, destDoc,destSheet
	
	destURL = "J:\nouveau_classeur.ods" 'à modifier bien sûr
	destURL = ConvertToURL(destURL)
	destDoc.StoreAsUrl(destURL,array())
End Sub

Sub CopySheet(sourceDoc,sourceSheet, destDoc,destSheet)
	Dim dispatcher As Object, sourceController As Object, destController As Object
	
	dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

	sourceController = sourceDoc.currentController
	sourceController.Select sourceSheet
	dispatcher.executeDispatch(sourceController.frame, ".uno:Copy", "", 0, Array())
	
	destController = destDoc.currentController
	destController.Select destSheet
	dispatcher.executeDispatch(destController.frame, ".uno:Paste", "", 0, Array())
End Sub

entièrement dans la langue de Shakespear (sauf les commentaires) pour ne choquer personne

Je ne comprends pas l'allusion

[Mobydick_62]

Bonsoir à tous,
Merci alhazred pour ton aide. C'est exactement ce que je recherchais.
Je passe donc en résolu.