[Résolu][Base] ouvrir un Rapport depuis un Formulaire

[agrandjean]

Bonjour à toutes et tous
Je suis parvenu à créer (pas tout seul) une macro permettant d'ouvrir un formulaire à partir d'un formulaire principal qui s'ouvre à l'ouverture de la base.
Par contre je n'ai pas pu trouver d'exemple d'ouverture de Rapport depuis ce même formulaire général.

Si quelqu'un pouvait me donner un exemple de macro pour ça je lui en serait reconnaissant.

Merci d'avance

Ci-joint ma base : je veux ouvrir le Rapport RDevis depuis le formulaire FormulairePrincipal

[Jamelot]

Bonjour,
Ne sachant pas quelle version tu utilises, je présume qu'il s'agit de la dernière.
Dans ce cas, la méthode pour ouvrir un formulaire est plus simple que celle que tu utilises :

Code: Tout sélectionner   AgrandirRéduire

Sub OuvForm(evt As Object)
'*************************************************************************************************
'Lancée par l'appui sur un bouton
' Permet l'ouverture d'un formulaire dont le nom est renseigné dans le champ
' "Complément d'information" du bouton
'=================================================================================================
Dim oForms As Object
Dim sNomForm As String
   sNomForm = evt.Source.Model.tag
   oForms = ThisComponent.Parent.FormDocuments
   IF oForms.hasByName(sNomForm)  Then
     oForms.getByName(sNomForm).open
   Else
     MsgBox("Formulaire inconnu : " & sNomForm, 16)
   End IF
End Sub


L'utilisation de cette macro est précisée dans les commentaires.
Celle pour ouvrir un rapport est similaire :

Code: Tout sélectionner   AgrandirRéduire

'*************************************************************************************************
Sub OuvRap(evt As Object)
'*************************************************************************************************
'Lancée par l'appui sur un bouton
' Permet l'ouverture d'un rapport dont le nom est renseigné dans le champ
' "Complément d'information" du bouton
'=================================================================================================
Dim oForms As Object
Dim sNomRapport As String
   sNomRapport = evt.Source.Model.tag
   oForms = ThisComponent.Parent.ReportDocuments
   IF oForms.hasByName(sNomRapport)  Then
     oForms.getByName(sNomRapport).open
   Else
     MsgBox("Rapport inconnu : " & sNomRapport, 16)
   End IF
End Sub


PS : Une faute d'orthographe dans ton titre rend plus difficile les recherches sur ce sujet.

[agrandjean]

La version utilisée est bien la 3.1.1
Les macros que tu m'a envoyéées sont parfaites et fonctionnent parfaitement.
Je te remercie encore de ton amabilité.

Alain