Car moi j'ai cette macro qui me permet d'ouvrir un fichier mais dans un nouveau document et non de l'importer dans une feuille.
Code : Tout sélectionner
Sub CSVOpen
' Cette ligne pour sélectionner dans une boîte de dialogue
sUrl = BrowseForFile("Sélectionner un bon de commande JETI", "Bon de commande", "d:\Jeti\Bestell", "*.bst")
' Cette ligne pour toujours importer le CSV de la même manière
sFilter = "9,,ANSI,1," ' Tab (Chr(9)) delimiter, no text delimiter, ANSI coding
if sFilter <>"" then
o = loadCSVfromURL(sUrl, sFilter, false)
endif
End Sub
'----- Code classique, plus rien à modifier
function loadCSVfromURL(sUrl as String, sFilter as String, bHidden as Boolean) as Object
Dim aProps(2) As New com.sun.star.beans.PropertyValue
aProps(0).Name = "FilterName"
aProps(0).Value = "Text - txt - csv (StarCalc)"
aProps(1).Name = "FilterOptions"
aProps(1).Value = sFilter
aProps(2).Name = "Hidden"
aProps(2).Value = bHidden
loadCSVfromURL = StarDesktop.loadComponentFromURL(sUrl, "_blank", 0, aProps())
end function
function BrowseForFile(sTitle as String, sFilterName as String, sStartDirectory as String, sFilter as String) as String
dim ars
o=CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
o.setTitle(sTitle)
o.appendFilter( sFilterName & " (" & sFilter & ")", sFilter)
o.setMultiSelectionMode(false)
o.setDisplayDirectory(ConvertToUrl(sStartDirectory))
if o.execute() = com.sun.star.ui.dialogs.ExecutableDialogResults.OK then
ars = o.getFiles()
BrowseForFile = ars(UBound(ars))
else
BrowseForFile = ""
endif
end function
function GetFilterOptionsFromCSVImportDialog(sUrl) as String
GetFilterOptionsFromCSVImportDialog = ""
oSFA = createUNOService ("com.sun.star.ucb.SimpleFileAccess")
oInputStream = oSFA.openFileRead(sUrl)
Dim aProps(3) as new com.sun.star.beans.PropertyValue
aProps(0).Name = "FilterOptions"
aProps(0).Value = ""
aProps(1).Name = "URL"
aProps(1).Value = sUrl
aProps(2).Name = "FilterName"
aProps(2).Value = "Text - txt - csv (StarCalc)"
aProps(3).Name = "InputStream"
aProps(3).Value = oInputStream
o = createUnoService("com.sun.star.ui.dialogs.FilterOptionsDialog")
o.setPropertyValues(aProps())
if o.execute() = com.sun.star.ui.dialogs.ExecutableDialogResults.OK then
aPropOut = o.getPropertyValues()
GetFilterOptionsFromCSVImportDialog = aPropOut(0).Value
endif
oInputStream.closeInput()
end function
