This documentation is an update of skycam96 tutorial found at
Create an unattended / silent install of OpenOffice.org 3
Some instruction provided by skycam96 may or are not applicable for OpenOffice.org 3.3.0. Therefore, I have rewrite his manual and code in order to fit unattended installation of OpenOffice.org 3.3.0.
Note:
All part of this manual was tested with Windows XP Professional Service Pack 3. However, may run on other OS. (32bit version).
This manual and the codes herein are dynamic and therefore are subjected to changes without notice
Know issues:
BiggestDawg has report syntax error when installing extensions. (see bug June 30, 2011)
Some extension does not accept "Y" to agree the license when prompt. (see bug July 06, 2011)
The main objectives continue to be skycam96 objectives plus one:
1. Make the install as simple and straightforward as possible
2. Set OpenOffice.org to saves files in the Microsoft Office formats
3. Avoid any registration prompts, wizards, etc.
4. Install extra extension
Requirements:
• Computer installed with XP Service Pack 3 32bit version (Professional). May run on other OS.
• Latest Java offline version at - http://www.java.com/en/download/manual.jsp
• OpenOffice.org 3.3.0 without JRE installer at - http://download.services.openoffice.org ... _en-US.exe
• Modified XCD files: calc.xcd, impress.xcd and writer.xcd
• Notepad
• Extension:
- DisableFirstStartWzd_ooo33.oxt - http://wiki.services.openoffice.org/w/i ... _ooo33.oxt
- Impress Runner - http://extensions.services.openoffice.o ... ownload/23
Export as Image (see bug July 06, 2011) - http://extensions.services.openoffice.o ... nload/5076
Preparing Modified XCD files
If you don’t want that OpenOffice save as Microsoft Office format as default, you can go to next section; Creating Installation Folder.
If you want you can download the modified files in a self extract zip file at http://ppsolution.net/downloads/UpdatesOpenOffice.exe or do it manually from the instructions below.
Note: the self extracted package and his contents are free of virus, malware or anti spyware
Self Extracted Zip Instructions
• Double click the package
• Extract the files on your desktop in a folder named Config
Manual Instructions
• Install OpenOffice on a system or in a Virtual Machine in order to create the modified XCD files.
• When Prompt extract the Installation files on your desktop (default)
• After install OpenOffice do not run OpenOffice
• Rename the extracted folder, "OpenOffice.org 3.3 (en-US) Installation Files" into OOo
• Create a new folder on your desktop and rename it into Config
• Browse to C:\Program Files\OpenOffice.org 3\Basis\share\registry
• Copy calc.xcd, impress.xcd and writer.xcd
• Paste calc.xcd, impress.xcd and writer.xcd into the Config folder on your desktop
• Open the each file with Notepad
• Use Find (Menu Edit > Find) to locate the word “ooSetupFactoryDefaultFilter” (without quote)
Note: for writer press “Find next” twice
• Replace the default value with the following value (CASE SENSITIVE)
- calc8 := MS Excel 97
impress8 := MS PowerPoint 97
writer8 := MS Word 97
Creating Installation folder - OOoSilent
Now we will create a folder structure for the installation files. If you like to use your own folder structure, you may, as long as you avoid spaces in your folder names and you are able to modify the codes in Setup.cmd file
• Create a main directory (C:\OOoSilent)
• Create a sub folder and rename it into Java (C:\OOoSilent\Java)
• Copy the Java offline setup file in this folder
• Move the OOo folder from desktop to OOoSilent folder (C:\OOoSilent\OOo)
• Move the Config folder from desktop to OOoSilent folder (C:\OOoSilent\Config), if created
• Create a new folder in the main directory
• Rename the folder into Extension (C:\OOoSilent\Extension)
• In the extension folder we will place all extension, primarily DisableFirstStartWzd_ooo33.oxt
Creating the Setup.cmd file
We will use a batch file in order to install Java, OpenOffice, OpenOffice extension and configure OpenOffice.
• Open notepad
• Copy the following code and paste it into notepad
• Save the file as Setup.cmd in the main directory (C:\OOoSilent)
• Close the file
Note: The batch required Java 6.27. Please read the section "REM CHECK IF INSTALLATION INSTALLED SUCCESSFUL" in order to adjust the codes for another version
Code: Select all
@echo off
Title OpenOffice.org Installation
REM Setting variable
Set setupdir=%CD%
Set javadir="%setupdir%\Java"
Set ooodir="%setupdir%\ooo"
Set extdir="%setupdir%\extension"
Set cnfdir="%setupdir%\config"
if exist "C:\Program Files\OpenOffice.org 3" set OOoprog="C:\Program Files\OpenOffice.org 3"
if exist "C:\Program Files (x86)\OpenOffice.org 3" set OOoprog="C:\Program Files (x86)\OpenOffice.org 3"
Set configdir=%OOoprog%\Basis\share\registry
REM INSTALLING JAVA
Echo Installing Java
CD %javadir%
for %%f in (*.exe) do "%%f" /s /v "/qb" ADDLOCAL=ALL IEXPLORER=1 MOZILLA=1
cls
REM INSTALLING OPENOFFICE.org
Echo Installing OpenOffice
CD %ooodir%
for %%f in (*.msi) do msiexec /qb /norestart /i "%%f" ADDLOCAL=ALL
cls
REM INSTALLING OPENOFFICE.org EXTENSIONS
Echo Installing OpenOffice Extension
CD %extdir%
for %%f in (*.oxt) do echo yes | %OOoprog%\program\unopkg add -f -s --shared %CD%\%%f
cls
REM COPY MODIFIED XCD FILES *** if exist
If not exist %cnfdir% goto endofblock1
Echo Copy OpenOffice Configuration files
CD %cnfdir%
for %%f in (*.xcd) do copy /Y %cd%\"%%f" %configdir%
: endofblock1
cls
REM REMOVE OLDER OPENOFFICE FOLDER
Echo Clean Up
cd "C:\Documents and Settings\All Users\Start Menu\Programs"
if exist "%CD%\OpenOffice.org 2.3" rmdir /s /Q "%CD%\OpenOffice.org 2.3"
if exist "%CD%\OpenOffice.org 2.4" rmdir /s /Q "%CD%\OpenOffice.org 2.4"
cd "C:\Program Files"
if exist "%CD%\OpenOffice.org 2.3" rmdir /s /Q "%CD%\OpenOffice.org 2.3"
if exist "%CD%\OpenOffice.org 2.4" rmdir /s /Q "%CD%\OpenOffice.org 2.4"
cd "C:\Program Files (x86)"
if exist "%CD%\OpenOffice.org 2.3" rmdir /s /Q "%CD%\OpenOffice.org 2.3"
if exist "%CD%\OpenOffice.org 2.4" rmdir /s /Q "%CD%\OpenOffice.org 2.4"
cls
REM CHECK IF INSTALLATION INSTALLED SUCCESSFUL
:: The current checker check for java; jre-6u27-windows-i586-s.exe
:: If you have a newer version of java you will need to update the reg export string
:: for version for java; jre-6u24-windows-i586-s.exe the last part of the string will be ..-87B4-2F83216024FF}
:: for version for java; jre-6u26-windows-i586-s.exe the last part of the string will be ..-87B4-2F83216026FF}
:: you can detect both Java and OpenOffice Registry string using Regshot or TotalUninstaller during setup
REG Query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{26A24AE4-039D-4CA4-87B4-2F83216027FF}
if %errorlevel% EQU 0 set JAV=Install succesful
if %errorlevel% EQU 1 set JAV=Failed to Install
REG Query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{ED23E382-E5E3-4E21-B616-01FC59A40916}
if %errorlevel% EQU 0 set OOO=Install succesful
if %errorlevel% EQU 1 set OOO=Failed to Install
cls
Echo Installation Result
Echo.
Echo * Java %jav%
Echo * OpenOffice.org %ooo%
Echo Click any key to close this window
Pause > %TMP%\null
First of all make a backup of the OOoSilent folder. Zip (self extracting) or iso the content of OOoSilent. Burn, share over a Network or copy the content of OOoSilent to stick if you want to run the setup on other computers.
• If OpenOffice is installed on your system uninstall it.
• If OpenOffice was uninstalled (above step), run Command Prompt (CMD), run the following codes and exit cmd
- RMdir /s /Q “C:\Program Files\OpenOffice.org 3”
RMdir /s /Q “%APPDATA%\OpenOffice.org” (only if you have run OpenOffice after install)
• Run setup.cmd
History
June 30, 2011
- Bug solved: Syntax error when installing Extension (64 bit Operating system, not tested)
Cause: Open office install on 64 bit operating system in the folder "C:\Program Files (x86)\OpenOffice.org 3" instead of C:\Program Files\OpenOffice.org 3" as on xp or 32 bit Operating System
Solution: The script is adjusted in such way to detect whether the OpenOffice program folder is
- Bug solved: Extension prompt for license acceptance
Cause: Extension developer require several input method to accept their license. Some example are: Yes, Enter, Y, etc
Solution 1: Take out the extension causing problem from the installation
Solution 2: Adjust the code to install each extension manually. Take notice you need to define the input in the part Echo (to define) | %OOoprog%\pro....... and define the (full_extension_name_x)
- To do this (THIS IS AN EXAMPLE)
Replace the line
for %%f in (*.oxt) do echo yes | %OOoprog%\program\unopkg" add -f -s --shared %CD%\%%f
With
echo yes | %OOoprog%\program\unopkg" add -f -s --shared %CD%\(full_extension_name_1).oxt
echo Y | %OOoprog%\program\unopkg" add -f -s --shared %CD%\(full_extension_name_2).oxt
- To do this (THIS IS AN EXAMPLE)
• Test the script on Operating system greater then XP and 64bit version. Submit your input if you have run this manual and codes successful on other Operating system then XP SP3.
• Full automate script (this include auto download, auto creation of setup folders and auto installation)
• Include Remote Installation from Server or Local Machine (for Network Administrator only)
• Installation script for Linux distribution
Report Bugs
Please report bug at support@ppsolution.net or send me a PM. When sending bug send it in the following format.
subject; DATE (YYMMDD): Brief description of the issue
body message:
- Operating System:
Service Pack:
Operating system bit:
Issue:
Credits to
aqualung.............: For making this manual available in the tutorial section
skycam96 ...........: For the inspiration due his manual and codes
BiggestDawg........: For his input by submitting a bug report