[Solved] Get OOo version programatically

[Anderl.Heckmaier]

I have inherited some code that uses the Ooo SDK and am very new with this stuff. Anyone know how I can get the version of the Ooo app that I am hooked into?

thanks,
AH

[Villeroy]

A set of Basic functions to get/set values from the OOo registry.

Code: Select all

Function getOOoVersion() As String

  getOOoVersion = getOOoSetupValue("/org.openoffice.Setup/Product","ooSetupVersion")
end Function

Function getOOoSetupNode(sNodePath$)
Dim aConfigProvider, oNode, args(0) As new com.sun.star.beans.PropertyValue
	aConfigProvider = createUnoService("com.sun.star.configuration.ConfigurationProvider")
	args(0).Name = "nodepath"
	args(0).Value = sNodePath
	getOOoSetupNode = aConfigProvider.createInstanceWithArguments("com.sun.star.configuration.ConfigurationAccess", args())
End Function

Function getOOoSetupValue(sNodePath$,sProperty$)
Dim oNode
	oNode = getOOoSetupNode(sNodePath)
	getOOoSetupValue = oNode.getbyname(sProperty)
End Function

Function setOOoSetupValue(sNodePath$, sProperty$, sValue$) as Boolean
on error goto exitErr
Dim bReturn as Boolean, xconfig, xAccess
dim aArgs(0) as  Object
dim aPropValue as new  com.sun.star.beans.PropertyValue
	xconfig = CreateUnoService("com.sun.star.configuration.ConfigurationProvider")
	aPropValue.Name = "nodepath"
	aPropValue.Value = sNodePath
	aArgs(0) = aPropValue
	xAccess = xconfig.createInstanceWithArguments("com.sun.star.configuration.ConfigurationUpdateAccess",aArgs())
	xAccess.setPropertyValue(sProperty, sValue)
	xAccess.commitChanges()
	bReturn = True
exitErr:
	setOOoSetupValue = bReturn
End Function